Modifying some code by branching based on range of values

Code: [Select]

$FFE0:CD 24 A5  CMP $A524 = #$7F
$FFE3:B0 05     BCS $FFEA
$FFE5:A9 20     LDA #$20
$FFE7:65 02     ADC $0002 = #$20
$FFE9:60        RTS
$FFEA:CD 11 AC  CMP $AC11 = #$7F
$FFED:B0 FA     BCS $FFE9
$FFEF:A9 40     LDA #$40
$FFF1:65 02     ADC $0002 = #$20
$FFF3:60        RTS
This is my original idea and I based it on my DTE value checks, but I don't think I'm using the right code. I tried simplifying it by doing one CMP and BPL, but that also isn't working. What I'm trying to do is to have the game branch only when the data is between the specified range. Could I get some help on this? Thanks

Try these out, but beware of silliness.

Inclusive range check

Code: [Select]


    LDA someValue
    CMP lowerLimit

    ; fail on strictly less than (<)
    BCC .outOfBounds

    CMP upperLimit

    ; in other words, less than or equal to the upper limit (<=)
    BCC .success
    BEQ .success

    ; fall through to failure in the case of strictly greater than (>)

.outOfBounds:

    RTS

.success:

    PHA

    EOR #$FF
    PHA

    RTS ; end up somewhere semi-random!

Noninclusive range check

Code: [Select]


AlarmClock:

    LDA someValue
    CMP lowerLimit

    ; fail on less than or equal to (<=)
    BCC .outOfBounds
    BEQ .outOfBounds

    CMP upperLimit

    ; strictly less than makes for a fun time (<)
    BCC .success

    ; fall through to failure in the case of greater than or equal (>=)

.outOfBounds:

    RTS

.success:

    LDA (AlarmClock-1)
    PHA

    LDA (AlarmClock-1)>>8
    PHA

    RTS ; I got you babe!

   


So... A has your value from the script and the two locations A524 and AC11 hold the lower resp. upper boundary? If so, your second check should use a bcc presuming that you want to RTS if inside the boundary. If not, it should already work your way if AC11 holds (upper boundary +1).

cYa,

Tauwasser

Code: [Select]

$FFE0:CD 24 A5  CMP $A524 = #$7F
$FFE3:B0 05     BCS $FFEA
$FFE5:A9 20     LDA #$20
$FFE7:65 02     ADC $0002 = #$20
$FFE9:60        RTS
$FFEA:CD 11 AC  CMP $AC11 = #$7F
$FFED:B0 FA     BCS $FFE9
$FFEF:A9 40     LDA #$40
$FFF1:65 02     ADC $0002 = #$20
$FFF3:60        RTS
This is my original idea and I based it on my DTE value checks, but I don't think I'm using the right code. I tried simplifying it by doing one CMP and BPL, but that also isn't working. What I'm trying to do is to have the game branch only when the data is between the specified range. Could I get some help on this? Thanks

Is this for the NES?  If so, I'm a little confused as to why you're using ROM addresses ($A524, $AC11) with your compare instructions.  Usually you compare against an immediate value or a value in RAM.  Are the upper and lower bounds you want to check against stored at those addresses in ROM?  If so, why?  Wouldn't it be easier to use immediate values?

What is the range of data that you want to branch on?

Code: [Select]

$F0CA:B1 00     LDA ($00),Y @ $ABAD = #$47 A:32 X:12 Y:0F P:nvUbdizc
$F0CC:9D 02 03  STA $0302,X @ $0314 = #$7F A:47 X:12 Y:0F P:nvUbdizc
$F0CF:C6 06     DEC $0006 = #$01           A:47 X:12 Y:0F P:nvUbdizc
$F0D1:D0 F5     BNE $F0C8                  A:47 X:12 Y:0F P:nvUbdiZc
$F0D3:E8        INX                        A:47 X:12 Y:0F P:nvUbdiZc
$F0D4:8E 01 03  STX $0301 = #$00           A:47 X:13 Y:0F P:nvUbdizc
$F0D7:18        CLC                        A:47 X:13 Y:0F P:nvUbdizc
$F0D8:A9 20     LDA #$20
Yeah, NES. This the code for this particular routine. What I'm trying to get it to do is to have the code branch only when A524-AC11 are read from 00 and basically want to just alter LDA #$20 to #$40

You want to check the values at $00 and $01 then:

Code: [Select]

lda $00
cmp #$24                        ;checking for $a524 - low byte of address
bne somewhere

lda $01
cmp #$a5                        ;high byte of address
beq a524_found

Something like that.

Yeah, NES. This the code for this particular routine. What I'm trying to get it to do is to have the code branch only when A524-AC11 are read from 00 and basically want to just alter LDA #$20 to #$40

Like RedComet said, you'll want to check what values are stored in your $00/$01 pointer.  Since addresses are 16-bit, it gets a little complicated.  Check out this code:

Code: [Select]

    lda $01                      ;check high byte of the pointer
    cmp #$A5
    bcc .out_of_range            ;if its less than A5, we are out of range
    beq .check_lower_boundary_lo ;else if equal to A5, we need to test the low byte
    cmp #$AD
    bcs .out_of_range            ;else if it is greater than or equal to AD, we are out of range   
    cmp #$AC
    beq .check_upper_boundary_lo ;else if equal to AC, we need to test the low byte
    bne .in_range                 ;else we are A6-AB, so no need to check the low byte
.check_lower_boundary_lo:
    lda $00
    cmp #$24         
    bcc .out_of_range        ;if low byte is less than 24, we are out of range
    bcs .in_range           ; else we are in range
.check_upper_boundary_lo:
    lda $00
    cmp #$12             ;if low byte is greater than or equal to 12, we are out of range
    bcs .out_of_range
.in_range:
    lda #$40                   ;i think this is what you wanted to do if in range?
    ;do stuff and return
.out_of_range:
    lda #$20
    ;do stuff and return

That's a lot of instructions, so you'll need some free space to fit it all in.